mirror of
https://github.com/xen-project/xen.git
synced 2026-10-28 02:01:24 +01:00
Olaf Hering
d45a0826d0
When xen is configured with --disable-ocamltools then oxenstored will still be the default if all required ocaml devel packages are installed. The reason is that xenstored.m4 is included before the ocamltools check. And xenstored.m4 does not use the result of --disable-ocamltools. Rearrange the code to check first for the presence of ocaml, then check --disable-ocamltools and finally decide what sort of xenstored should be the default. Signed-off-by: Olaf Hering <olaf@aepfle.de> Cc: Ian Campbell <ian.campbell@citrix.com> Cc: Ian Jackson <ian.jackson@eu.citrix.com> Cc: Stefano Stabellini <stefano.stabellini@eu.citrix.com> Cc: Wei Liu <wei.liu2@citrix.com> Acked-by: Ian Campbell <ian.campbell@citrix.com> [ ijc -- ran autogen.sh as requested]
57 lines
1.7 KiB
Plaintext
57 lines
1.7 KiB
Plaintext
AC_DEFUN([AX_XEN_OCAML_XENSTORE_CHECK], [
|
|
AS_IF([test "$ocamltools" = "n"], [
|
|
AC_MSG_ERROR([Missing ocaml dependencies for oxenstored, try installing ocaml ocaml-compiler-libs ocaml-runtime ocaml-findlib])
|
|
])
|
|
])
|
|
|
|
AC_DEFUN([AX_XEN_OCAML_XENSTORE_DEFAULTS], [
|
|
xenstore="oxenstored"
|
|
xenstored=$sbindir/oxenstored
|
|
AS_IF([test "$ocamltools" = "n"], [
|
|
xenstore="xenstored"
|
|
xenstored=$sbindir/xenstored
|
|
])
|
|
])
|
|
|
|
AC_DEFUN([AX_XENSTORE_OPTIONS], [
|
|
AS_IF([test "x$XENSTORE" = "x"], [
|
|
AC_ARG_WITH([xenstored],
|
|
AS_HELP_STRING([--with-xenstored@<:@=oxenstored|xenstored@:>@],
|
|
[This lets you choose which xenstore daemon you want, you have
|
|
two options: the original xenstored written in C (xenstored)
|
|
or the newer and robust one written in Ocaml (oxenstored).
|
|
The oxenstored daemon is the default but can only
|
|
be used if you have ocaml library / build dependencies solved,
|
|
if you have not specified a preference and do not have ocaml
|
|
dependencies resolved we'll enable the C xenstored for you. If
|
|
you ask for oxenstored we'll complain until you resolve those
|
|
dependencies]),
|
|
[
|
|
AS_IF([test "x$withval" = "xxenstored"], [
|
|
xenstore=$withval
|
|
xenstored=$sbindir/xenstored
|
|
])
|
|
AS_IF([test "x$withval" = "xoxenstored"], [
|
|
xenstore=$withval
|
|
xenstored=$sbindir/oxenstored
|
|
AX_XEN_OCAML_XENSTORE_CHECK()
|
|
])
|
|
AS_IF([test "x$withval" != "xoxenstored" && test "x$withval" != "xxenstored"], [
|
|
AC_MSG_ERROR([Unsupported xenstored specified, supported types: oxenstored xenstored])
|
|
])
|
|
],
|
|
[
|
|
AX_XEN_OCAML_XENSTORE_DEFAULTS()
|
|
])
|
|
])
|
|
])
|
|
|
|
AC_DEFUN([AX_XENSTORE_SET], [
|
|
XENSTORE=$xenstore
|
|
|
|
AS_IF([test "x$XENSTORED" = "x"], [
|
|
XENSTORED=$xenstored
|
|
])
|
|
AC_SUBST(XENSTORED)
|
|
])
|